Retrieving Data

Retrieving XML

• To retrieve the XML structure of an AdvancedTree instance, use its data property. This will return the structure typed as a String, so to get actual XML, pass the result to ActionScript's XML constructor.

// returns tree structure as XML typed as String, with no whitespace
var structure:String = tree.data;

// returns tree structure as XML typed as String, which is then converted to XML
var structure:String = tree.data;
var xml:XML = new XML(structure);

• To retrieve the XML in a more human-legible form, use the AdvancedTree's toString() method. This will add whitespace and tabs to the string returned.

// returns tree structure as XML typed as String, with whitespace
var structure:String = tree.toString();
textfield.text = structure;

• TreeNode's have toXML() and toString() methods that can also be used on each TreeNode instance to return the node's individual structure. toXML() returns the node's structure as XML formatted as a string with no whitespace, while toString() returns the XML as formatted as a string with whitespace.

// returns the selected node's structure as XML typed as String, with no whitespace
var structure:String = tree.selectedNode.toXML();
var xml:XML = new XML(structure);

// returns the selected node's structure as XML typed as String, with whitespace
var structure:String = tree.selectedNode.toString();
textfield.text = structure;

Accessing Node Data

• A TreeNode's name may be set or retrieved at any time using the nodeName property.

// return node's name
trace(tree.selectedNode.nodeName);

// sets node's name
tree.selectedNode.nodeName = "user";

• Node values may be accessed and set using the TreeNode's nodeValue property.

// return node's value
trace(tree.selectedNode.nodeValue);

// sets node's value
tree.selectedNode.nodeValue = "This is a text string.";

• Attributes of a node can be accessed using either the TreeNode's attributes property, which returns an associative array, or by using the getAttribute() and setAttribute() methods.

// sets a node's attribute value for "ID"
tree.selectedNode.attributes["ID"] = 500;

// sets a node's attribute value for "ID" (alternative)
tree.selectedNode.setAttribute("ID", 500);

// retrieves a node's attribute value for "ID"
var ID:Number = tree.selectedNode.attributes["ID"];

// retrieves a node's attribute value for "ID" (alternative)
var ID:Number = tree.selectedNode.getAttribute("ID");

• To find a node's index within its parent's childNodes, use either the property index or the method findIndex().

// inserts a new node before the selected node
import com.flashloaded.ui.tree.nodes.TreeNode;
var selectedNode:TreeNode = tree.selectedNode;
var index:uint = selectedNode.findIndex();
var parent:TreeNode = selectedNode.parentNode;
var newNode:TreeNode = new TreeNode();
parentNode.addNodeAt(index, newNode);
tree.refresh();

// inserts a new node before the selected node (alternative and condensed)
import com.flashloaded.ui.tree.TreeNode;
tree.selectedNode.parentNode.addNodeAt(tree.selectedNode.index, new TreeNode());
tree.refresh();

• One special TreeNode property, nodeLevel returns a node's level within the tree hierarchy.

// traces the level of the currently selected node
trace(tree.selectedNode.nodeLevel);

Accessing Children, Parents and Siblings

• A TreeNode's children can be accessed using the childNodes property, which returns an array of TreeNodes.

// runs through all of a node's children and deselects them
import com.flashloaded.ui.tree.nodes.TreeNode;
var children:Array = tree.selectedNode.childNodes;
for each (var node:TreeNode in children) {
  tree.deselectNode(node);
}

• The number of children that a TreeNode instance has can be accessed using either its numChildren property or its getNumChildren() method, both of which return an unsigned integer value.

// runs through all of a node's children and deselects them
var children:Array = tree.selectedNode.childNodes;
for (var i:uint = 0; i < tree.selectedNode.numChildren; i++) {
  tree.deselectNode(children[i]);
}

// runs through all of a node's children and deselects them (alternative)
var children:Array = tree.selectedNode.childNodes;
var num:uint = tree.selectedNode.getNumChildren();
for (var i:uint = 0; i < num; i++) {
  tree.deselectNode(children[i]);
}

• firstChild and lastChild can be used on a TreeNode instance to quickly access the first or last childnode, respectively.

// gets the select node's first child and closes it
tree.closeNode(tree.selectedNode.firtChild);


• A TreeNode's parent node can be accessed using the parentNode property.

// gets the select node's parent and closes it
tree.closeNode(tree.selectedNode.parentNode);


• A TreeNode's siblings property can be used to get an array of the node's parent's children (including the specified node through which the property is accessed).

// deselects all of a node's siblings
import com.flashloaded.ui.tree.nodes.TreeNode;
var siblings:Array = tree.selectedNode.siblings;
for each (var node:TreeNode in siblings) {
  if (node == tree.selectedNode) continue;
  tree.deselectNode(node);
}

• previousSibling and nextSibling can be used on a TreeNode instance to quickly access the childnodes before and after the specified node in its parent's childNodes array.

// removes the node's previous sibling
tree.removeNode(tree.selectedNode.previousSibling);

// removes the node's next sibling
tree.removeNode(tree.selectedNode.nextSibling);

Searching Nodes

• To find a node in an AdvancedTree instance with a specified attribute value, use the AdvancedTree's findAttributeValue() method, which returns the first node with the specified value. This is useful especially if unique IDs are assigned to the nodes.

// finds the node with the ID of 123
import com.flashloaded.ui.tree.nodes.TreeNode;
var node:TreeNode = tree.findAttributeValue("ID", 123);
tree.selectAndOpen(node);

• findAttributeValue() can be used on TreeNode instances as well, which can help limit searches.

// finds the node with the ID of 123 in the first child of the root
import com.flashloaded.ui.tree.nodes.TreeNode;
var node:TreeNode = tree.rootNode.firstChild.findAttributeValue("ID", 123);
tree.selectAndOpen(node);

• findAttributeValueForNodeType() can also be used on both the AdvancedTree and TreeNode instances to search only nodes of a certain type (type is equivalent to the node name).

// finds the user node with the ID of 123 in the tree
import com.flashloaded.ui.tree.nodes.TreeNode;
var node:TreeNode = tree.findAttributeValueForNodeType("user", "ID", 123);
tree.selectAndOpen(node);

// finds the user node with the ID of 123 in the first child of the root
import com.flashloaded.ui.tree.nodes.TreeNode;
var node:TreeNode = tree.rootNode.firstChild.findAttributeValueForNodeType("user", "ID", 123);
tree.selectAndOpen(node);